* (Вопрос) Как можно сгенерировать единую таблицу, содержащую:
	результаты кросстабуляции, хи-квадрат Пирсона и меру Фи (Phi)?.
* (Ответ) Автор: Raynald Levesque, 18.12.2004, http://www.spsstools.net .

* Определим для этой целим макрос.

*////////////////////////.
DEFINE !ctab(var1=!CHAREND('/') /var2=!CHAREND('/') /title=!TOKENS(1))

OMS  
    /SELECT  TABLES
    /IF COMMANDS=['Crosstabs']   SUBTYPES=['Crosstabulation']
    /DESTINATION FORMAT =SAV NUMBERED='TableNb'  OUTFILE='c:\\temp\\crosstabs1.sav'
    /TAG="OMS1".
OMS  
    /SELECT  TABLES
    /IF COMMANDS=['Crosstabs']    LABELS=['Chi-Square Tests']
    /DESTINATION FORMAT =SAV NUMBERED='TableNb'  OUTFILE='c:\\temp\\crosstabs2.sav'
    /TAG="OMS2".
OMS  
    /SELECT  TABLES
    /IF COMMANDS=['Crosstabs']    LABELS=['Symmetric Measures']
    /DESTINATION FORMAT =SAV NUMBERED='TableNb'  OUTFILE='c:\\temp\\crosstabs3.sav'
    /TAG="OMS3".

CROSSTABS
  /TABLES=!var1  BY !var2 
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ PHI
  /CELLS= COUNT
  /COUNT ROUND CELL .

OMSEND.
GET FILE='c:\\temp\\crosstabs1.sav' .
SAVE OUTFILE='c:\\temp\\crosstabs1.sav' /DROP= Command_ Subtype_ Label_.

GET FILE='c:\\temp\\crosstabs2.sav'  .
SELECT IF Var1="Pearson Chi-Square".
RENAME VARIABLES (Value=Chi2Value).
SAVE OUTFILE='c:\\temp\\crosstabs2.sav' /DROP= Command_ Subtype_ Label_ Var1 .

GET FILE='c:\\temp\\crosstabs3.sav'  .
SELECT IF Var2="Phi".
RENAME VARIABLES (Value=PhiValue).
SAVE OUTFILE='c:\\temp\\crosstabs3.sav'  /DROP= Command_ Subtype_ Label_ Var1 Var2.

MATCH FILES FILE='c:\\temp\\crosstabs1.sav'  
    /TABLE='c:\\temp\\crosstabs2.sav'
    /TABLE='c:\\temp\\crosstabs3.sav'
    /BY=TableNb
    /DROP=Var3.
VARIABLE LABELS PhiValue "Фи (Phi)" df "Число ст. свободы" Chi2Value "Хи-квадрат" .
SUMMARIZE
  /TABLES=Var1 TO Chi2Value df Asymp.Sig.2sided PhiValue Approx.Sig
  /FORMAT=VALIDLIST NOCASENUM TOTAL
  /TITLE=!title
  /MISSING=VARIABLE
  /CELLS=NONE .

!ENDDEFINE.
*////////////////////////.


** Пример 1 **.

GET FILE='c:\\program files\\spss\\employee data.sav'.
SET MPRINT=YES.
!ctab var1=gender minority /var2=jobcat /title='Обобщение таблиц сопряжённости (пол и меньшинства * категория занятости)'.
SET MPRINT=NO.

** Пример 2 **.

GET FILE='c:\\program files\\spss\\employee data.sav'.
SET MPRINT=YES.
!ctab var1=jobcat /var2=gender minority /title='Обобщение таблиц сопряжённости (категория занятости * поли и меньшинства)'.
SET MPRINT=NO.