*(Вопрос) Имеется .sav-файл без данных, но с описанными переменными, метками значений и т.д., 
 которые мне нужны.
* Сами данные находятся в другом файле.
  Как можно слить оба файла таким образом, чтобы разместить данные в описанных переменных?
   Порядок переменных в файле с данными в точности соответствует файлу-макету, 
   но имена переменных другие.

*(Ответ) Выслан эл. почтой автору вопроса. Ответил: Raynald Levesque, 08.03.2002.


DATA LIST LIST /a b c.
BEGIN DATA
1 1 2
2 3 4
END DATA.
SAVE OUTFILE='c:\\temp\\file with data.sav'. /* Файл с данными*/


* Следующий файл имеет единственное наблюдение, состоящее из пропусков.
DATA LIST LIST /x y z.
BEGIN DATA
.
END DATA.
VARIABLE LABELS x 'переменная X' y 'переменная Y' z 'переменная Z'.
VALUE LABELS y 1 'метка для y=1' 3 'метка для y=3'
		/z 2 'метка для z=2' 4 'метка для z=4'.
SAVE OUTFILE='c:\\temp\\file with labels only.sav'. /*Файл с описанием переменных*/


******* Начало преобразований.
GET FILE='c:\\temp\\file with data.sav'.
N OF CASES 1.
FLIP.
RENAME VARIABLE (case_lbl=dumname).
SAVE OUTFILE='c:\\temp\\dumname.sav' /KEEP=dumname.

GET FILE='c:\\temp\\file with labels only.sav'.
FLIP.
RENAME VARIABLE (case_lbl=varname).

MATCH FILES /FILE=*
 /FILE='C:\\Temp\\dumname.sav'.
EXECUTE.

* Создаём синтаксис для переименования переменных в файле 'file with data.sav'.
WRITE OUTFILE='c:\\temp\\rename variable.sps'
        /"RENAME VARIABLES ("dumname"="varname").".
EXECUTE.

GET FILE='c:\\temp\\file with data.sav'.
INCLUDE 'c:\\temp\\rename variable.sps'.
APPLY DICTIONNARY FROM 'c:\\temp\\file with labels only.sav'.
SAVE OUTFILE='c:\\temp\\data and labels.sav'. /*Файл с описанием переменных и данными*/