* Тема: Стандартизированные показатели величины эффекта Гласса, Хеджеса и Кохена.
* Ключевые слова: Glass, Hedges & Cohen, сила, эффект, стандартизированный, несмещенная, оценка, t-проверка, t-тест, группа, записать в файл данных.
* Опубликован: SPSSX-L 05.06.2002; обновлено 08.10.2004, перевод: 27.10.2008.
* Автор: Marta.
* Перевод: А. Балабанов.
* Размещение: http://www.spsstools.ru/Syntax/T-Test/StandardizedEffectsSize.txt (.sps).
* Проверено: SPSS 15.0.0.

*(Вопрос) Я провёл серию t-проверок для неравных по величине групп, и хотел бы
 теперь посчитать показатель силы эффекта d Кохена (Cohen's d). Я вижу, что в SPSS
 этой статистики в качестве стандартной опции нет. Как мне посчитать её, имея стандартную
 выдачу? Может, есть какой-то макрос?

*(Ответ) 

* Ниже я прилагаю обновление для кода, который я опубликовала 2 года назад.
* Вычисляются стандартизированные показатели силы эффекта Гласса, Хеджеса и Кохена (Glass, Hedges & Cohen)
* вместе с их стандартными ошибками. Все эти показатели добавляются в файл данных.
* Marta, 08.10.2004, mailto:biostatistics@terra.es 

* d Кохена - это просто (среднее1-среднее2)/Sp, где
* Sp - стандартное отклонение разности средних:
* Sp=sqrt((n1-1)*var1+(n2-1)*var2)/(n1+n2-2)).
* - var1=дисперсия выборки 1 (Sd1^2);
* - var2=дисперсия выборки 2 (Sd2^2).

* Если размеры изучаемых выборок малы, лучше использовать в качестве меры силы 
* эффекта несмещённую оценку, называемую g Хеджеса (Hedges' g):
* hedges g=cohen&*(1-(3/(4*(n1+n2)-9))).

* Если дисперсии неравны, иногда используется показатель стандартизированной разницы средних, 
* называемый d Гласса (Glass' d): (среднее1-среднее2)/Sd2, где
(Sd2 = стандартное отклонение в контрольной группе).

* Всю необходимую информацию для этих расчётов можно найти в таблицах выдачи SPSS.

* Обновлённый код (08.10.2004) *.

* Пример данных (замените вашими собственными данными, сохранив имена переменных) *.
* После номера теста первая группа из 3-х переменных - данные для экспериментальной группы, вторая - для контрольной.
DATA LIST LIST /test(A8) meantr sdtr(2F8.2) ntr(F8.0)
 meanco sdco(2F8.2) nco(F8.0).
BEGIN DATA
1 35   9 17 24    8 18
2 43  10 15 37    7 16
3 40 2.3 18 32 2.54 19
END DATA.
 
* Анализ *.
MATRIX.
GET test  /VAR=test.
GET mean1 /VAR=meantr.
GET sd1   /VAR=sdtr.
GET n1    /VAR=ntr.
GET mean2 /VAR=meanco.
GET sd2   /VAR=sdco.
GET n2    /VAR=nco.
PRINT {mean1,sd1,n1,mean2,sd2,n2}
 /FORMAT='F8.1'
 /TITLE='Исходные данные (в агрегированном виде)'
 /RNAMES=test
 /CLABELS='Среднее1','SD1','N1','Среднее2','SD2','N2'.
COMPUTE n=n1+n2.
COMPUTE poolvar=((n1-1)&*(sd1&**2)+(n2-1)&*(sd2&**2))/(n-2) .
COMPUTE glass=(mean1-mean2)/sd2.
COMPUTE se_glass=SQRT((n/(n1&*n2))+((glass&**2)/(2&*(n2-1)))).
COMPUTE cohen=(mean1-mean2)/SQRT(poolvar).
COMPUTE se_cohen=SQRT((n/(n1&*n2))+((cohen&**2)/(2&*(n-2)))).
COMPUTE hedges=cohen&*(1-(3/(4&*(n)-9))).
COMPUTE se_hedge=SQRT((n/(n1&*n2))+((hedges&**2)/(2&*(n-3.94)))).
PRINT {glass,se_glass,cohen,se_cohen,hedges,se_hedge}
 /FORMAT='F8.3'
 /RNAMES=test
 /CLABELS='Гласс','SE(D)','Кохен','SE(d)','Хеджес','SE(g)'
 /TITLE='Стандартизированные меры силы эффекта'.
COMPUTE data={glass,se_glass,cohen,se_cohen,hedges,se_hedge}.
COMPUTE namevec={'glass','seglass','cohen','secohen','hedges','sehedges'}.
SAVE data /OUTFILE='c:\\temp\\data.sav' /NAMES=namevec.
END MATRIX.
 
MATCH FILES /FILE=*
 /FILE='c:\\temp\\data.sav'.
EXECUTE.