1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
/* (Вопрос) Требуется передать имя переменной из файла данных в качестве аргумента */
/* макроса. Затем я хочу, чтобы макрос работал со значениями этой переменной. */

/* Допустим, я передаю имя переменной V1 в макрос. V1 может принимать значения 243, */
/* 78, 432 или 8. Я хочу передать эти значения уже макропеременной. То есть что-то вроде...*/
/* !DO !I !IN(!MACVAR) . */
/*   итерации со значениями переменной V1... */
/* !DOEND .*/

/* Возможно ли это? */


/* (Ответ) Размещён в новостной группе SPSS, 19.11.2002. Автор: Raynald Levesque. */
/*  Следующий код делает то, что вам надо. */

SET MPRINT=no.
*////////////////////.
DEFINE !getval(fpath=!TOKENS(1) 
		/varn=!TOKENS(1))

GET FILE=!fpath.
COMPUTE nobreak=1.
AGGREGATE
  /OUTFILE=*
  /BREAK=!varn
  /nbval = N(nobreak).
COMPUTE nobreak=1.
MATCH FILES FILE=* /BY nobreak /LAST=last.

DO IF $CASENUM=1.
- WRITE OUTFILE='c:\\temp\\syntax.sps' /'DEFINE !macvar()'!varn.
ELSE IF NOT last.
- WRITE OUTFILE='c:\\temp\\syntax.sps' /' '!varn.
ELSE.
- WRITE OUTFILE='c:\\temp\\syntax.sps' /' '!varn'!ENDDEFINE.'.
END IF.
EXECUTE.


GET FILE=!fpath.
INCLUDE 'c:\\temp\\syntax.sps'.
!ENDDEFINE.
*////////////////////.


SET MPRINT=yes.

* Пример.

!getval fpath ='c:\\program files\\spss\\employee data.sav'
	 varn  =educ.

* Вот содержимое файла syntax.sps, сгенерированного макросом.
DEFINE !macvar() 8
 12
 14
 15
 16
 17
 18
 19
 20
 21!ENDDEFINE.